mirror of
https://github.com/EpochModTeam/DayZ-Epoch.git
synced 2025-12-14 20:13:13 +03:00
89bca2c94b
This commit fixes partly the floating loot issue. The whole problem is not fixable. It is a problem with different components. The main point is that the position can be half water and half not. The second is the building collision and the collision of the loot object. Normally setPosATL should do its work but the object moves on the placement. Adding a special handling for buildings that are mostly over water did the best job so far. With fixWaterPos = 1; in the building class which has those floating loot problems, the position gets converted to ASL which is better over water but not always. Some loot objects are still floating a bit but I could reach all of them. It is a way better as before.
93 lines
2.8 KiB
Plaintext
93 lines
2.8 KiB
Plaintext
/*
|
|
Spawns loot at the given building.
|
|
|
|
Parameters:
|
|
obj - building to spawn loot at
|
|
type - classname of building
|
|
config - building configs (type, loot chance, loot positions. loot refresh timer)
|
|
|
|
Usage:
|
|
[building,classname,_config] call building_spawnLoot;
|
|
|
|
Author:
|
|
Foxy
|
|
*/
|
|
|
|
#include "\z\addons\dayz_code\util\Vector.hpp"
|
|
#include "\z\addons\dayz_code\loot\Loot.hpp"
|
|
|
|
private ["_vectorUp","_obj","_config","_lootChance","_lootPos","_lootGroup","_worldPos","_group","_smallGroup","_type"];
|
|
|
|
_obj = _this select 0;
|
|
_type = _this select 1;
|
|
_config = _this select 2;
|
|
_vectorUp = vectorUp _obj;
|
|
if (Vector_Angle(Vector_UP,_vectorUp) > 20) exitWith { 0 };
|
|
_lootChance = getNumber (_config >> "lootChance");
|
|
|
|
if (_lootChance <= 0 or ([_obj] call DZE_SafeZonePosCheck)) exitWith {};
|
|
|
|
_group = getText(_config >> "lootGroup");
|
|
_lootPos = getArray (_config >> "lootPos");
|
|
_lootPos = [_lootPos,5] call fn_shuffleArray;
|
|
|
|
// Military buildings spawn matching loot.
|
|
if (_group in ["Military","MilitaryIndustrial"]) then {
|
|
_lootGroup = Loot_SelectSingle(Loot_GetGroup(_group));
|
|
_smallGroup = _lootGroup select 2;
|
|
_lootGroup = Loot_GetGroup(_lootGroup select 1);
|
|
} else {
|
|
_lootGroup = Loot_GetGroup(_group);
|
|
};
|
|
|
|
{
|
|
//Get the world position of the spawn position
|
|
_worldPos = _obj modelToWorld _x;
|
|
_worldPos set [2, 0 max (_worldPos select 2)];
|
|
|
|
//Delete existing lootpiles within 1m of spawn location
|
|
{
|
|
deleteVehicle _x;
|
|
dayz_currentWeaponHolders = dayz_currentWeaponHolders - 1;
|
|
} count (_worldPos nearObjects ["ReammoBox", 1]);
|
|
|
|
if (_lootChance > random 1 && {dayz_currentWeaponHolders < dayz_maxMaxWeaponHolders}) then {
|
|
Loot_SpawnGroup(_lootGroup, _worldPos, _type);
|
|
};
|
|
}
|
|
foreach _lootPos;
|
|
|
|
// EPOCH ADDITION
|
|
// lootPosSmall are additional positions in lockers, on shelves, etc. for small objects only.
|
|
// Example: soda cans, small ammo, pistols, bandage, etc.
|
|
|
|
if (isArray (_config >> "lootPosSmall")) then {
|
|
_lootPos = getArray (_config >> "lootPosSmall");
|
|
|
|
if (!isNil "_smallGroup") then {
|
|
_lootGroup = Loot_GetGroup(_smallGroup);
|
|
} else {
|
|
_lootGroup = Loot_GetGroup((_group) + "Small");
|
|
};
|
|
|
|
if (_lootGroup >= 1) then {
|
|
_lootPos = [_lootPos,5] call fn_shuffleArray;
|
|
{
|
|
//Get the world position of the spawn position
|
|
_worldPos = _obj modelToWorld _x;
|
|
_worldPos set [2, 0 max (_worldPos select 2)];
|
|
//Delete existing lootpiles within 1m of spawn location
|
|
{
|
|
deleteVehicle _x;
|
|
dayz_currentWeaponHolders = dayz_currentWeaponHolders - 1;
|
|
} count (_worldPos nearObjects ["ReammoBox", 1]);
|
|
|
|
if (_lootChance > random 1 && {dayz_currentWeaponHolders < dayz_maxMaxWeaponHolders}) then {
|
|
Loot_SpawnGroup(_lootGroup, _worldPos, _type);
|
|
};
|
|
} foreach _lootPos;
|
|
} else {
|
|
diag_log format["Loot group small: %1 does not exist", ((getText(_config >> "lootGroup")) + "Small")];
|
|
};
|
|
};
|