Organize files a bit and removed non source pbo's

SQF/dayz_code/actions/pzombie/pz_attack.sqf

@@ -0,0 +1,33 @@
+private ["_target","_ent","_rnd","_move","_isZombie"];
+_target = _this select 3;
+_ent = _target;
+
+// remove menu
+player removeAction s_player_pzombiesattack;
+s_player_pzombiesattack = 1;
+
+_rnd = (round(random 9)) + 1;
+_move = "ZombieStandingAttack" + str(_rnd);
+player playMoveNow _move;
+
+_isZombie = _ent isKindOf "zZombie_base";
+
+if(player distance _target < 5) then {
+
+	if (_ent isKindOf "Animal" or _isZombie) then {
+		_ent setDamage 1;
+	} else {
+		//["usecBreakLegs",[_target,player]] call broadcastRpcCallAll;
+		usecBreakLegs = [_target,player];
+		publicVariable "usecBreakLegs";
+	};
+
+	[player,"hit",0,false] call dayz_zombieSpeak;
+
+};
+
+sleep 1;
+
+player switchmove "";
+
+s_player_pzombiesattack = -1;

SQF/dayz_code/actions/pzombie/pz_feed.sqf

@@ -0,0 +1,95 @@
+private ["_item","_regen","_isAnimal","_animalType","_isMan","_config","_isListed","_qty","_ctrlBlood","_rnd","_move","_display","_control","_bloodVal"];
+_item = _this select 3;
+// _ent = _item;
+
+disableSerialization;
+
+player removeAction s_player_butcher;
+s_player_butcher = 1;
+
+if(!(alive _item)) then {
+
+    _rnd = (round(random 4)) + 1;
+	_move = "ZombieFeed" + str(_rnd);
+	player playMoveNow _move;
+
+	sleep 1;
+
+	// player playActionNow "PutDown";
+	[player,50,true,(getPosATL player)] spawn player_alertZombies;
+
+	[player,"gut",0,false] call dayz_zombieSpeak;
+
+	_item setVariable["meatHarvested",true,true];
+
+	sleep 1;
+
+	_regen = 200;
+
+	_isAnimal = _item isKindOf "Animal";
+	_animalType = typeOf _item;
+	_isMan = _item isKindOf "Man";
+
+	if(_isAnimal) then {
+		_config = 		configFile >> "CfgSurvival" >> "Meat" >> _animalType;
+		_isListed =		isClass (_config);
+
+		_qty = 1;	
+		if (_isListed) then {
+			_qty =	getNumber (_config >> "yield");
+			_regen = _qty * 200;
+		};
+
+	} else {
+
+		if(_isMan) then { 
+			_regen == 12000; 
+		};
+	};
+
+
+	r_player_blood = r_player_blood + _regen;
+	if (r_player_blood > r_player_bloodTotal) then {
+		r_player_blood = r_player_bloodTotal;
+	};
+
+	player setVariable ["messing",[dayz_hunger,dayz_thirst],true];
+	player setVariable["USEC_BloodQty",r_player_blood,true];
+	player setVariable["medForceUpdate",true];
+
+	dayz_lastDrink = time;
+	dayz_thirst = 0;
+
+	dayz_lastMeal =	time;
+	dayz_hunger = 0;
+
+	//["dayzPlayerSave",[player,[],true]] call callRpcProcedure;
+	dayzPlayerSave = [player,[],true];
+	publicVariableServer "dayzPlayerSave";
+
+	[player,"eat",0,false] call dayz_zombieSpeak;
+
+	// todo: dump loot on ground and then remove
+
+	//Ensure Control is visible
+	_display = uiNamespace getVariable 'DAYZ_GUI_display';
+	_control = 	_display displayCtrl 1301;
+	_control ctrlShow true;
+
+    _ctrlBlood = 	_display displayCtrl 1300;
+	_bloodVal =		r_player_blood / r_player_bloodTotal;
+	if (_bloodVal >= 0.2) then {
+		_ctrlBlood ctrlShow true;
+	};
+
+	//Ensure Control is visible
+	_display = uiNamespace getVariable 'DAYZ_GUI_display';
+	_control = 	_display displayCtrl 1302;
+	_control ctrlShow true;
+
+
+	cutText [format[(localize  "str_player_consumed"),_animalType], "PLAIN DOWN"];
+	player switchmove "";
+};
+
+s_player_butcher = -1;

SQF/dayz_code/actions/pzombie/pz_vision.sqf

@@ -0,0 +1,70 @@
+
+private ["_gen","_caller","_id","_NV","_NVOn","_OldAperture","_NV1","_NV2","_NV3"];
+_gen = _this select 0;
+_caller = _this select 1;
+_id = _this select 2;
+
+_gen removeAction _id;
+
+// get first rbg + m
+_NV1 = player getvariable ["NV1",[1.8,-1.5,-0.5,0]];
+_NV2 = player getvariable ["NV2",[2.4,0.6,0.3,-0.3]];
+_NV3 = player getvariable ["NV3",[-0.6,0.8,0.3,0.6]];
+
+_NV = player getvariable ["NV", ["OFF", 0.1]];
+_NVOn = (_NV select 0);
+_OldAperture = (_NV select 1);
+
+if(_NVOn == "ON") 
+exitwith
+{
+	setaperture -1;
+	ppEffectDestroy ppColor;
+	ppEffectDestroy ppBlur;
+	player setvariable ["NV",["OFF",_oldAperture]];
+	player addAction ["Vision", "\z\addons\dayz_code\actions\pzombie\pz_vision.sqf", [], 0, false, true, "nightVision", "_this == _target"];
+};
+
+ppEffectDestroy ppColor;
+ppEffectDestroy ppBlur;
+
+
+ppColor = ppEffectCreate ["ColorCorrections", 1999];  
+ppColor ppEffectEnable true;  
+ppColor ppEffectAdjust [1, 1, 0, _NV1, _NV2, _NV3];
+ppColor ppEffectCommit 0;
+
+/*
+ppInversion = ppEffectCreate ['colorInversion', 2555];
+ppInversion ppEffectEnable false;
+ppInversion ppEffectAdjust [1,1,1];
+ppInversion ppEffectCommit 0;
+*/
+
+diag_log format ["DEBUG: Aperture : %1 First %2 Second %3 Third %4", _OldAperture, _NV1,_NV2,_NV3];
+
+
+ppBlur = ppEffectCreate ["dynamicBlur", 505];
+ppBlur ppEffectEnable true;  
+ppBlur ppEffectAdjust [.2];
+ppBlur ppEffectCommit 0;
+
+
+aperture = 0.0001;
+while { aperture < _oldAperture } do
+{
+	aperture = aperture + 0.0005;
+	setAperture aperture;
+	sleep 0.001;
+};
+
+
+
+player setVariable ["NV", ["ON", _oldAperture]];
+player setVariable ["NV1",_NV1];
+player setVariable ["NV2",_NV2];
+player setVariable ["NV3",_NV3];
+
+
+player addAction ["Vision", "\z\addons\dayz_code\actions\pzombie\pz_vision.sqf", [], 0, false, true, "nightVision", "_this == _target"];
+exit;

SQF/dayz_code/actions/pzombie/pz_vision_ap.sqf

@@ -0,0 +1,28 @@
+private ["_gen","_caller","_id","_NV","_NVOn","_new","_inc","_newap"];
+
+_gen = _this select 0;
+_caller = _this select 1;
+_id = _this select 2;
+
+// _gen removeAction _id;
+
+// array from tweaking settings
+_new = _this select 3;
+_inc = _new select 0;
+
+// get Aperture
+_NV = player getvariable ["NV",["OFF", 0.1]];
+
+_newap = (_NV select 1)+_inc;
+
+_NVOn = (_NV select 0);
+
+if(_NVOn == "ON") then {
+
+	setAperture _newap;
+
+	player setVariable ["NV", ["OFF", _newap]];
+} else {
+	player setVariable ["NV", ["ON", _newap]];
+};
+cutText [format["%1 %2","NV",_newap], "PLAIN DOWN"];

SQF/dayz_code/actions/pzombie/pz_vision_rbg1.sqf

@@ -0,0 +1,55 @@
+private ["_gen","_caller","_id","_NV","_NVOn","_index","_NV1","_NV2","_NV3","_new","_NVx","_increase","_newap"];
+
+_gen = _this select 0;
+_caller = _this select 1;
+_id = _this select 2;
+
+// _gen removeAction _id;
+
+// array from tweaking settings
+_new = _this select 3;
+
+_NVx = _new select 0;
+
+// get first rbg + m
+_NV = player getvariable [_NVx,[0.0, 0.0, 0.0, 0.0]];
+
+_increase = (_new select 1);
+
+_index = 0;
+{
+	_NV set [_index,(_NV select _index) + _x];
+
+	_index =_index + 1;
+} forEach _increase;
+
+// set rgb + m 
+player setVariable [_NVx, _NV];
+cutText [format["%1 %2",_NVx,_NV], "PLAIN DOWN"];
+
+_NV = player getvariable ["NV",["OFF", 0.1]];
+_NVOn = (_NV select 0);
+_newap = (_NV select 1);
+
+if(_NVOn == "ON") then {
+
+	_NV1 = player getvariable ["NV1",[0,0,0,0]];
+	_NV2 = player getvariable ["NV2",[0,0,0,0]];
+	_NV3 = player getvariable ["NV3",[0,0,0,0]];
+
+	ppEffectDestroy ppColor;
+	ppEffectDestroy ppBlur;
+
+	ppColor = ppEffectCreate ["ColorCorrections", 1999];  
+	ppColor ppEffectEnable true;  
+	ppColor ppEffectAdjust [1, 1, 0, _NV1, _NV2, _NV3];
+	ppColor ppEffectCommit 0;
+
+	diag_log format ["DEBUG: Aperture : %1 First %2 Second %3 Third %4", _newap, _NV1,_NV2,_NV3];
+
+	player setVariable ["NV", ["OFF", _newap]];
+} else {
+	player setVariable ["NV", ["ON", _newap]];
+}; 
+
+exit;